Hoe BLOB opslaan als bestand in PL/SQL?

Hier geef ik een voorbeeld om BLOB-gegevens op te slaan als een bestand in PL/SQL. BLOB-gegevens kunt u ophalen uit de tabel met BLOB-kolom, of u kunt het uit een bestand op de schijf halen.

PL/SQL-functievoorbeeld om BLOB als bestand op te slaan

De onderstaande procedure heeft de volgende drie argumenten:

1. Naam Oracle Directory-object (als i_dir).
2. Opslaan als bestandsnaam (als i_file).
3. BLOB-gegevens (als i_blob).

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Test

Het volgende PL/SQL-blok roept de bovenstaande procedure aan door het Oracle-directoryobject, de bestandsnaam en de BLOB-gegevens door te geven. Voor de BLOB-gegevens gebruik ik de GET_BLOB-functie waarvan ik een voorbeeld heb gegeven in mijn vorige blogpost:Get BLOB from a File in PL/SQL. In het onderstaande geval haalt het de BLOB-gegevens op uit een bestand mijnbestand.jpg van de locatie MY_DIR en slaat het op in het bestand abc.jpg op de locatie IMG_DIR.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Nu kunt u de locatie van de IMG_DIR-map controleren voor het bestand dat is gemaakt via BLOB.

Zie ook:

• Hoe maak ik een Oracle Directory-object aan?
• Meer informatie over het extraheren van BLOB-gegevens uit Oracle Table met Toad