Oracle:is er een manier om recente SQL-syntaxisfouten te krijgen?

U kunt een trigger maken in Oracle die alle fouten registreert (of vrijwel alle - NO_DATA_FOUND wordt niet als een fout beschouwd). In het onderstaande voorbeeld wordt elke fout in het schema vastgelegd in de TRACK_DETAIL-tabel (fout in één rij, mislukte SQL in de volgende). Je kunt het meer verfijnd maken met een volgnummer, datum/tijd enz.

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

Vergeet niet om de trigger te laten vallen (of uit te schakelen) als je ermee klaar bent.