Hoe de versie van oracle-provider voor ole-db te controleren. OraOLEDB.Oracle-provider

U kunt bijvoorbeeld de tool RegDllView gebruiken. Zoeken naar "OraOLEDB", resultaat kan dit zijn:

Een eenvoudigere benadering zou zijn om naar uw ORACE_HOME\bin . te gaan directory en zoek het bestand OraOLEDB??.dll . Controleer de versie met de rechtermuisknop -> Eigenschappen -> Details.

U krijgt echter alleen de versie van het bestand, dit betekent niet noodzakelijk dat deze DLL ook geregistreerd en klaar voor gebruik is.

Of gebruik dit VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

OLE DB-provider kan bestaan ​​in 32-bits of/en in 64-bits, dus u kunt het script twee keer uitvoeren:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs