Verzamelingen manipuleren

In het tweede geval ben je tenminste een tabeldefinitie kwijt. Deze verklaring:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

declareert alleen object (of record) type, geen tabel.

Je moet het dus in 2 stappen doen:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Daarna heb je wat syntaxiscorrecties in het script nodig:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

UPDATE

Oplossing hierboven relatief traag vanwege groot aantal contextwisselingen. Maar vergelijking van complexe objecttype-instanties kan niet rechtstreeks in PL/SQL worden gedaan zonder wat extra werk.
Om Oracle te laten weten of objectinstanties hetzelfde of verschillend zijn, moeten we toewijzings- of bestelmethode voor objecttype . Beide soorten methoden zijn niet toegestaan, dus er moet een juiste worden gekozen. MAP-methoden werken sneller en bestellen is in ons geval niet nodig, dus ga ervoor:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Implementatie:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Daarna is het mogelijk om objecten te testen op gelijkheid in PL/SQL-code, zoals eenvoudig varchar2 in eerste voorbeeld van vraag:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/