CLOB-waarde in out/return van plsql (ongeldige LOB-locator gespecificeerd:ORA-22275)

Op dit punt:

    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob

... je l_clob OUT-parameter is niet geïnitialiseerd. Er een lege CLOB van maken werkt ook niet (dus zelfs als je l_clob hebt gemaakt een IN OUT-parameter zou het nog steeds klagen) als de documentatie voor empty_clob vermeldt :

U kunt in plaats daarvan een tijdelijke CLOB gebruiken door een aanroep toe te voegen aan dbms_lob.createtemporary(l_clob, true) voordat u het probeert te gebruiken:

...
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
      ...

En dan hoef je geen initiële lege waarde op te geven wanneer je het aanroept:

declare
  myVal clob;
begin
  dbst_load_a_file('Konotop.svg', myVal);
  DBMS_OUTPUT.PUT_LINE(myVal);
end;
/

Dit werkt ook als een functie:

create or replace 
function dbst_load_a_file( p_file_name in varchar2) return clob
as
    l_clob    clob;
    l_bfile   bfile;
    dst_offset  number := 1 ;
    src_offset  number := 1 ;
    lang_ctx    number := DBMS_LOB.DEFAULT_LANG_CTX;
    warning     number;
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
    , SRC_BFILE    => l_bfile
    , AMOUNT       => dbms_lob.getlength( l_bfile )
    , DEST_OFFSET  => dst_offset
    , SRC_OFFSET   => src_offset
    , BFILE_CSID   => DBMS_LOB.DEFAULT_CSID
    , LANG_CONTEXT => lang_ctx
    , WARNING      => warning);
    dbms_lob.fileclose( l_bfile );
    return l_clob;
end;
/

select dbst_load_a_file('Konotop.svg') from dual;

Of gebruik in een insert zoals in uw bewerkte vraag.