Hoe databasemelding naar C++-toepassing te krijgen

Een benadering is het gebruik van Advanced Queuing van Oracle . Voor dat doel moet je een wachtrij (en een wachtrijtabel) opzetten en een PL/SQL-procedure schrijven die wacht op het volgende bericht in de wachtrij.

De C++-kant roept dan de PL/SQL-procedure aan, die terugkeert wanneer de volgende gebeurtenis heeft plaatsgevonden.

Aan de Oracle-kant moet u DBMS_SCHEDULER of een vergelijkbare faciliteit om het evenement te creëren , d.w.z. om op het juiste moment een nieuw bericht in de wachtrij te plaatsen.

Het is nog steeds een verkiezingsaanpak. Er is echter absoluut geen activiteit tussen twee evenementen.

Bijwerken:

Hier is wat voorbeeldcode.

Initiële configuratie van de wachtrij (het bericht bevat een numerieke en een tekstwaarde):

grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;


CREATE TYPE sample_payload_type AS OBJECT
(
  cmd  VARCHAR2(20),
  id   NUMBER
);


BEGIN
  DBMS_AQADM.CREATE_QUEUE_TABLE (
    queue_table        => 'sample_queue_table',
    queue_payload_type => 'sample_payload_type',
    sort_list          => 'ENQ_TIME',
    compatible         => '10.0'
  );
END;
/

BEGIN
  DBMS_AQADM.CREATE_QUEUE (
    queue_name         => 'sample_queue',
    queue_table        => 'sample_queue_table'
  );

  DBMS_AQADM.START_QUEUE (
    queue_name         => 'sample_queue'
  );
END;
/

Pakketkop:

create or replace package sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  );


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  );

end sample_queue_pkg;
/

Pakket lichaam:

create or replace package body sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  )
  is
    dequeue_options dbms_aq.dequeue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;

    NO_MESSAGE_RECEIVED EXCEPTION;
    PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);

  begin
    dequeue_options.wait := i_max_wait;
    DBMS_AQ.DEQUEUE (
      queue_name => 'appuser.sample_queue',
      dequeue_options => dequeue_options,
      message_properties => message_properties,
      payload => message,
      msgid => message_handle
    );

    o_cmd := message.cmd;
    o_id := message.id;

  exception
    when NO_MESSAGE_RECEIVED then
      o_cmd := null;
      o_id := null;

  end get_next_msg;


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  )
  is
    enqueue_options dbms_aq.enqueue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;
    message_id NUMBER;

  begin
    message := sample_payload_type(i_cmd, i_id);
    DBMS_AQ.ENQUEUE(
      queue_name => 'appuser.sample_queue',
      enqueue_options => enqueue_options,
      message_properties => message_properties,
    payload => message,
      msgid => message_handle
    );
  end put_msg;

end sample_queue_pkg;
/

De databaseserver kan een bericht sturen met de volgende code:

sample_queue_pkg.put_msg('run_task', 8234);
commit;

De C++-server kan wachten op berichten (en deze ontvangen) die de opgeslagen sample_queue_pkg.get_next_msg aanroepen . De parameter i_max_wait specificeert de maximale wachttijd in seconden op het volgende bericht. U wilt waarschijnlijk een lus implementeren die wacht op het volgende bericht en dit verwerkt totdat het een signaal ontvangt dat de server op het punt staat te stoppen.