Biedt Oracle de manier om meerdere substrings te retourneren van een string/clob-rij die is geparseerd?

Iets als dit misschien:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Dit kan als volgt worden gebruikt:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Als je niet op 11.x zit, moet je zelf het retourtype definiëren:

create type char_table as table of varchar(4000);

en verander de functiedeclaratie in:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....