Tabelfunctie met bulkverzameling genereert ongeldig gegevenstype

U probeert typen op pakketniveau te gebruiken in gewone SQL, wat niet is toegestaan. De typen die in het pakket zijn gedeclareerd, zijn niet zichtbaar voor of geldig buiten PL/SQL (of zelfs niet in gewone SQL-instructies binnen PL/SQL). Een verkorte versie van wat je doet:

create or replace package types as
    type my_rec_type is record (dummy dual.dummy%type);
    type my_table_type is table of my_rec_type index by binary_integer;
end types;
/

create or replace package p42 as
    function get_table return types.my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return types.my_table_type is
        my_table types.my_table_type;
    begin
        select * bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

SQL Error: ORA-00902: invalid datatype

Zelfs binnen het pakket, als je een procedure had die de tabelfunctie probeerde te gebruiken, zou er een fout optreden. Als je hebt toegevoegd:

    procedure test_proc is
    begin
        for r in (select * from table(get_table)) loop
            null;
        end loop;
    end test_proc;

... de body-compilatie van het pakket zou mislukken met ORA-22905: cannot access rows from a non-nested table item .

U moet de typen declareren op schemaniveau, niet in een pakket, dus met behulp van de SQL create type commando :

create type my_obj_type is object (dummy varchar2(1));
/

create type my_table_type is table of my_obj_type;
/

create or replace package p42 as
    function get_table return my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return my_table_type is
        my_table my_table_type;
    begin
        select my_obj_type(dummy) bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

DUMMY
-----
X