Hibernate-codering van database volledig transparant voor toepassing

Als u het werk in de toepassing beëindigt, kunt u aangepaste typen voor de slaapstand gebruiken en voegt het niet zoveel wijzigingen aan uw code toe.

Hier is een gecodeerd aangepast stringtype dat ik heb gebruikt:

import org.hibernate.usertype.UserType
import org.apache.log4j.Logger

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class EncryptedString implements UserType {

  // prefix category name with 'org.hibernate.type' to make logging of all types easier
  private final Logger _log = Logger.getLogger('org.hibernate.type.com.yourcompany.EncryptedString')

  Object nullSafeGet(ResultSet rs, String[] names, Object owner) throws SQLException {
    String value = rs.getString(names[0])

    if (!value) {
      _log.trace "returning null as column: $names[0]"
      return null
    }

    _log.trace "returning '$value' as column: $names[0]"
    return CryptoUtils.decrypt(value)
  }

  void nullSafeSet(PreparedStatement st, Object value, int index) throws SQLException {
    if (value) {
      String encrypted = CryptoUtils.encrypt(value.toString())
      _log.trace "binding '$encrypted' to parameter: $index"
      st.setString index, encrypted
    }
    else {
      _log.trace "binding null to parameter: $index"
      st.setNull(index, Types.VARCHAR)
    }
  }

  Class<String> returnedClass() { String }

  int[] sqlTypes() { [Types.VARCHAR] as int[] }

  Object assemble(Serializable cached, Object owner) { cached.toString() }

  Object deepCopy(Object value) { value.toString() }

  Serializable disassemble(Object value) { value.toString() }

  boolean equals(Object x, Object y) { x == y }

  int hashCode(Object x) { x.hashCode() }

  boolean isMutable() { true }

  Object replace(Object original, Object target, Object owner) { original }
}

en op basis hiervan zou het eenvoudig moeten zijn om vergelijkbare klassen te maken voor int, long, enz. Om het te gebruiken, voegt u het type toe aan de mapping-sluiting:

class MyDomainClass {

  String name
  String otherField

  static mapping = {
    name type: EncryptedString
    otherField type: EncryptedString
  }
}

Ik heb de methoden CryptoUtils.encrypt() en CryptoUtils.decrypt() weggelaten omdat dat niet Grails-specifiek is. We gebruiken AES, b.v. "Cipher cipher =Cipher.getInstance('AES/CBC/PKCS5Padding')". Wat je ook gaat gebruiken, zorg ervoor dat het een 2-way crypto is, d.w.z. gebruik geen SHA-256.