Perl en XPath:ontbrekende vermeldingen in databasetabel

Je hebt al een uitleg en een oplossing, maar ik stel de volgende wijzigingen voor

• Je moet je prepare de INSERT INTO SQL-instructie en vervolgens execute het binnen de lus. do heeft een veel grotere overhead

• De // ( descendant-or-self::node() ) XPath-constructie is duur en u moet het reserveren voor gevallen waarin u geen idee heeft waar het element zich in het document zal bevinden, wat zeer zeldzaam is. In dit geval de row1 elementen staan ​​op /database/row1s/row1 en de row2 elementen staan ​​op row2s/row2 ten opzichte van dat

• Het is veel overzichtelijker om verschillende scheidingstekens te gebruiken als u aanhalingstekens wilt gebruiken binnen een tekenreeks tussen aanhalingstekens. Bijvoorbeeld "My name is \"$name\"" is veel beter als qq{My name is "$name"}

Hier is een versie van uw programma die kan helpen.

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

uitvoer

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp