Meerdere rijen gegevens doorgeven aan een opgeslagen procedure

U kunt vrij eenvoudig meerdere waarden van een enkele tekenreeks splitsen. Stel dat u de tekenreeks als volgt kunt bundelen, met een komma om "kolommen" te scheiden en een puntkomma om "rijen" te scheiden:

foo, 20120101, 26; bar, 20120612, 32

(Hierbij wordt ervan uitgegaan dat dubbele punten en puntkomma's niet op natuurlijke wijze in de gegevens kunnen voorkomen; als ze dat wel kunnen, moet u andere scheidingstekens kiezen.)

U kunt een dergelijke split-routine bouwen, die een uitvoerkolom bevat waarmee u de volgorde kunt bepalen waarin de waarde in de oorspronkelijke tekenreeks verscheen:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY [object_id])
        FROM sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Dan kun je het als volgt opvragen (voor de eenvoud en illustratie behandel ik slechts 3 eigenschappen, maar je kunt dit extrapoleren voor 11 of n):

DECLARE @x NVARCHAR(MAX); -- a parameter to your stored procedure

SET @x = N'foo, 20120101, 26; bar, 20120612, 32';

;WITH x AS 
(
    SELECT ID = s.Number, InnerID = y.Number, y.Item 
    -- parameter and "row" delimiter here:
    FROM dbo.SplitStrings(@x, ';') AS s
    -- output and "column" delimiter here:
    CROSS APPLY dbo.SplitStrings(s.Item, ',') AS y
)
SELECT 
    prop1 = x.Item, 
    prop2 = x2.Item, 
    prop3 = x3.Item
FROM x 
INNER JOIN x AS x2 
ON x.InnerID = x2.InnerID - 1
AND x.ID = x2.ID
INNER JOIN x AS x3
ON x2.InnerID = x3.InnerID - 1
AND x2.ID = x3.ID
WHERE x.InnerID = 1
ORDER BY x.ID;

Resultaten:

prop1   prop2     prop3
------  --------  -------
foo     20120101  26
bar     20120612  32