Hoe krijg ik een bestand van BLOB in Oracle?

In deze zelfstudie leert u hoe u een bestand uit de BLOB-kolom in Oracle kunt halen. Om een ​​voorbeeld te geven:ik heb een tabel EXT_FILES gemaakt in Oracle en het volgende is de structuur van de tabel.

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

Voeg de gegevens in de bovenstaande tabel in. Als u niet weet hoe u een bestand in de BLOB-kolom moet invoegen, raadpleegt u het volgende artikel:Een bestand invoegen in de BLOB-kolom van Oracle Table?

U moet een Oracle-directoryobject in uw schema hebben gemaakt om de bestanden van de BLOB-kolom naar de schijf te krijgen. Geef de volgende opdracht om een ​​directory in Oracle te maken.

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

Het onderstaande is het Oracle Stored Procedure-voorbeeld, dat de records uit de EXT_FILES-tabel (met BLOB-gegevens) haalt met behulp van een cursor en vervolgens de bestanden één voor één uitpakt in de opgegeven map.

Oracle opgeslagen procedurevoorbeeld om het bestand uit de BLOB-kolom in Oracle te halen

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

Test

BEGIN
get_files_from_blob;
END;
/

Uitvoer

PL/SQL procedure successfully completed.

U kunt nu de locatie van het IMGDIR-mapobject voor de uitgepakte bestanden controleren.

Zie ook:

• BLOB-gegevens extraheren uit Oracle Table met Toad