Hoe het creditcardnummer te valideren en het type te identificeren met behulp van PL/SQL?

Hier geef ik een voorbeeld van een in PL/SQL opgeslagen functie om het creditcardnummer te valideren en het type te identificeren, of het nu een Visa-, MasterCard- of American Express-creditcard is. Ik controleer het creditcardnummer met behulp van het LUHN-algoritme dat wordt gebruikt om verschillende identificatienummers te valideren. Als het creditcardnummer geldig is, controleert de functie het type.

PL/SQL-functievoorbeeld om creditcardnummer en zijn type in Oracle te valideren

De volgende functie neemt een argument als creditcardnummer en valideert vervolgens het nummer met behulp van het Luhn-algoritme en retourneert het type. Momenteel ondersteunt deze PL/SQL-functie drie soorten creditcards, namelijk Visa, MasterCard en American Express. U kunt wijzigen om meer creditcardtypes toe te voegen. De functie CHECK_LUHN_ALGO om het nummer te controleren met behulp van het Luhn-algoritme is geschreven in de functie VALIDATE_CC, dus als u meer ondersteuning voor kaarttypes wilt toevoegen, hoeft u de functie CHECK_LUHN_ALGO niet te wijzigen, wijzigt u alleen het hoofdgedeelte van de functie VALIDATE_CC.

CREATE OR REPLACE FUNCTION validate_CC (cc_number IN VARCHAR2)
   RETURN VARCHAR2
IS
   v_ret_string   VARCHAR2 (100);

   FUNCTION check_luhn_algo (p_ccnumber VARCHAR2)
      RETURN NUMBER
   IS
      i          NUMBER;
      n_ntoi     SMALLINT;
      n_retval   SMALLINT;
      n_calc     NUMBER := 0;
      n_ntoc     NUMBER;
   BEGIN
      n_ntoc := LENGTH (p_ccnumber);

      FOR i IN 1 .. n_ntoc
      LOOP
         n_ntoi := TO_NUMBER (SUBSTR (p_ccnumber, n_ntoc + 1 - i, 1));

         n_calc :=
              n_calc
            + MOD (i, 2) * n_ntoi
            + MOD (i + 1, 2) * SIGN (-SIGN (n_ntoi - 4) + 1) * (2 * n_ntoi)
            +   MOD (i + 1, 2)
              * SIGN (SIGN (n_ntoi - 5) + 1)
              * (2 * n_ntoi - 9);
      END LOOP;

      n_retval := SIGN (MOD (n_calc, 10));

      RETURN n_retval;
   EXCEPTION
      WHEN OTHERS
      THEN
         RETURN 1;
   END check_luhn_algo;
BEGIN
   /* Credit card number is invalid if below funciton returns non zero value */
   IF check_luhn_algo (cc_number) != 0
   THEN
      v_ret_string := 'Not a valid Credit Card Number.';
      RETURN v_ret_string;
   ELSE
      v_ret_string := 'A Valid ';
   END IF;

   /* Credit card number is valid now check for its type */

   IF SUBSTR (cc_number, 1, 1) = '4'          /* check if it is a Visa card */
   THEN
      IF LENGTH (cc_number) = 13 OR LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'Visa Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) BETWEEN 51 AND 55  /* check if master card*/
   THEN
      IF LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'MasterCard Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) = 34 OR SUBSTR (cc_number, 1, 2) = 37 /* check if amex card */
   THEN
      IF LENGTH (cc_number) = 15
      THEN
         v_ret_string :=
            v_ret_string || 'American Express Credit Card Number.';
      END IF;
   ELSE
      v_ret_string := v_ret_string || 'But unable to identify its type.';
   END IF;

   RETURN v_ret_string;
EXCEPTION
   WHEN OTHERS
   THEN
      RETURN 'Error...';
END validate_CC;

Test

Wijzig de onderstaande tekenreeks 4047xxxxxxxxxxxx met uw Visa-, MasterCard- of Amex-creditcardnummer om te testen.

SET SERVEROUTPUT ON;

DECLARE
   RetVal      VARCHAR2 (100);
   CC_NUMBER   VARCHAR2 (100);
BEGIN
   CC_NUMBER := '4047xxxxxxxxxxxx';

   RetVal := VALIDATE_CC (CC_NUMBER);
   DBMS_OUTPUT.put_line (retval);
END;
/

Uitvoer

A Valid Visa Credit Card Number.
PL/SQL procedure successfully completed.

Opmerking: Test grondig voordat u het in uw app implementeert.

Zie ook:

• E-mailadres valideren met PL/SQL in Oracle