Hoe maak je een logbestand aan in Oracle met PL/SQL?

U hebt een PL/SQL-programma en u wilt van elke stap van uw code informatie in een tekstbestand vastleggen. Hier is een voorbeeld om een ​​logbestand in Oracle aan te maken met PL/SQL.

Logbestand maken in Oracle met PL/SQL-voorbeeld

Het volgende is een PL/SQL-procedure om de productprijs bij te werken met een percentage dat als parameter is doorgegeven. Het registreert ook de informatie van elke stap die in het programma plaatsvindt. Let op, u moet een directory-object hebben gemaakt in Oracle om de bestanden te kunnen schrijven. Bekijk deze link om te leren hoe u een directory-object maakt in Oracle.

CREATE OR REPLACE PROCEDURE prod_price_update (increase_pct IN NUMBER)
IS
   f_file        UTL_FILE.file_type;
   v_file_name   VARCHAR2 (100);
BEGIN
   v_file_name := 'log_' || TO_CHAR (SYSDATE, 'yyyymmdd_HH24miss') || '.log';
   f_file := UTL_FILE.fopen ('LOG_FILES', v_file_name, 'w');
   UTL_FILE.put_line (f_file, 'Log file ' || v_file_name);
   UTL_FILE.new_line (f_file);
   UTL_FILE.put_line (
      f_file,
      'Job started at: ' || TO_CHAR (SYSDATE, 'dd-mm-yyyy HH24:mi:ss'));
   UTL_FILE.put_line (
      f_file,
      'Price increment percentage value: ' || increase_pct || '%');

   UPDATE products
      SET prod_list_price =
             prod_list_price + (prod_list_price * increase_pct / 100);

   UTL_FILE.put_line (f_file,
                      'Number of products updated:  ' || SQL%ROWCOUNT);

   COMMIT;
   UTL_FILE.put_line (f_file, 'Records committed.');
   UTL_FILE.put_line (
      f_file,
      'Job finished successfully at: '
      || TO_CHAR (SYSDATE, 'dd-mm-yyyy HH24:mi:ss'));
   UTL_FILE.fclose (f_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (f_file)
      THEN
         UTL_FILE.put_line (f_file, 'Job finished with errors: ' || SQLERRM);
         UTL_FILE.fclose (f_file);
      END IF;
END;

Het programma testen

BEGIN
   PROD_PRICE_UPDATE (12);
END;
/

De uitvoer van het logbestand (log_20180919_214756.log)

Log file log_20180919_214756.log

Job started at: 19-09-2018 21:47:56
Price increment percentage value: 12%
Number of products updated:  72
Records committed.
Job finished successfully at: 19-09-2018 21:47:57

Zie ook:

• Schrijf CSV-bestanden in Oracle met PL/SQL