Oracle Doorzoek alle tabellen alle kolommen op string

U moet minimaal ALL_TAB_COLUMNS doorzoeken, niet ALL_TABLES

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

Als u echter naar een tekenreeks zoekt, wilt u zich vrijwel zeker beperken tot het zoeken naar kolommen waarin een tekenreeks kan worden opgeslagen. Het zou bijvoorbeeld geen zin hebben om in een DATE-kolom naar een tekenreeks te zoeken. En tenzij je veel a priori kennis hebt over wat een BLOB-kolom bevat en de mogelijkheid om de binaire opmaak van de BLOB-kolom te ontleden, zou het geen zin hebben om in een BLOB-kolom naar een tekenreeks te zoeken. Gezien dat, vermoed ik dat je iets meer wilt zoals

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

Dit gaat natuurlijk waanzinnig langzaam - je zou elke tabel één keer volledig scannen voor elke tekenreekskolom in de tabel. Met redelijk grote tabellen en een gemiddeld aantal stringkolommen zal dat waarschijnlijk een hele tijd duren.