Knip alle tabellen in een database in SQL Server af - SQL Server / TSQL-zelfstudie, deel 55

Scenario:

Laten we eens nadenken over een database die we gebruiken voor ons ETL-proces en we noemen dat database-staging. We willen alle tabellen in de ochtend afkappen, zodat deze kunnen worden gebruikt voor het dagelijkse proces. Eén manier is om onze Truncate-instructie voor elke tabel te schrijven, maar tabellen kunnen worden verwijderd of er kunnen ook nieuwe tabellen worden gemaakt. We willen een query schrijven die we kunnen gebruiken om alle tabellen uit een database af te kappen en we hoeven onze Truncate-instructies niet te herschrijven.

Als de tabellen geen Primary Key -Foreign Key hebben relatie, kunnen we Truncate gebruiken. Maar we hebben vaak tabellen waarnaar wordt verwezen door andere tabellen. We kunnen de Truncate-instructie niet gebruiken voor die tabellen. De enige manier om deze tabellen af te kappen is door de Foreign Key Constraint te verwijderen voordat u gaat Truncaten en daarna Truncate and Recreate Relationship daarna.

De onderstaande code kan worden gebruikt om alle tabellen uit de database af te kappen. Als tabellen de Pk-Fk-relatie hebben, zal het script eerst de beperkingen voor externe sleutels verwijderen en vervolgens die tabellen afkappen en ten slotte de beperkingen voor externe sleutels opnieuw maken. wijzend naar de juiste database en server! Veel succes met het afkappen van alle tabellen uit een SQL Server-database.

-- Drop Temp Tables if Exists

 IF OBJECT_ID('tempdb..#DropConstraint') IS NOT NULL
  DROP TABLE #DropConstraint

 IF OBJECT_ID('tempdb..#CreateConstraint') IS NOT NULL
  DROP TABLE #CreateConstraint

 IF OBJECT_ID('tempdb..#TempTruncateTables') IS NOT NULL
    DROP TABLE #TempTruncateTables

-- Drop Constraint Script Save in #DropConstraint Temp Table

SELECT 'ALTER TABLE ' + '['
       + Schema_name(o.schema_id) + '].['
       + OBJECT_NAME(FK.parent_object_id) + ']'
       + ' DROP  CONSTRAINT ' + '[' + FK.name + ']' AS DropConstraintQuery

INTO #DropConstraint

 FROM   sys.foreign_keys AS FK
       INNER JOIN sys.foreign_key_columns AS FKC
               ON FK.OBJECT_ID = FKC.constraint_object_id
       INNER JOIN sys.objects O
               ON O.OBJECT_ID = FKC.parent_object_id

-- Create Constraint Script Save in #CreateConstraint Temp Table

SELECT 'ALTER TABLE ' + '['
       + Schema_name(o.schema_id) + '].' + '['
       + OBJECT_NAME(FK.parent_object_id) + ']'
       + ' ADD CONSTRAINT ' + '[' + FK.name
       + '] Foreign Key (['
       + (SELECT name
          FROM   sys.columns c
          WHERE  c.OBJECT_ID = FKC.parent_object_id
                 AND c.column_id = FKC.parent_column_id)
       + ']) REFERENCES ' + '['
       + Schema_name(o.schema_id) + '].['
       + (SELECT name
          FROM   sys.objects o
          WHERE  OBJECT_ID = FKC.referenced_object_id)
       + '] (['
       + (SELECT name
          FROM   sys.columns c
          WHERE  c.OBJECT_ID = FKC.referenced_object_id
                 AND c.column_id = FKC.referenced_column_id)
       + '])' AS CreateConstraintQuery

INTO #CreateConstraint

 FROM   sys.foreign_keys AS FK
       INNER JOIN sys.foreign_key_columns AS FKC
               ON FK.OBJECT_ID = FKC.constraint_object_id
       INNER JOIN sys.objects o
               ON FKC.parent_object_id = o.OBJECT_ID

-- Build Truncate Statement for all the tables and save into #TempTruncateTables

 SELECT 'Truncate table ' + Schema_name(schema_id)
       + '.' + name AS TruncateTableQuery

INTO #TempTruncateTables
FROM sys.tables

 WHERE  TYPE = 'U'
       AND is_ms_shipped = 0

GO

-- Drop Constraints
DECLARE @DropConstraintQuery AS VARCHAR(4000)

 DECLARE DropConstraintCur CURSOR FOR
  SELECT DropConstraintQuery
  FROM   #DropConstraint

OPEN DropConstraintCur
FETCH Next FROM DropConstraintCur
INTO @DropConstraintQuery

 WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL
      SET @SQL=@DropConstraintQuery
      EXEC (@SQL)
      PRINT ' Query ::' + @DropConstraintQuery
            + 'Completed'
      FETCH Next FROM DropConstraintCur INTO @DropConstraintQuery
  END
CLOSE DropConstraintCur

DEALLOCATE DropConstraintCur
GO-- Truncate tables

DECLARE @TempTruncateTablesCur AS VARCHAR(4000)

DECLARE TempTruncateTablesCur CURSOR FOR
  SELECT TruncateTableQuery
  FROM   #TempTruncateTables

OPEN TempTruncateTablesCur
FETCH Next FROM TempTruncateTablesCur
INTO @TempTruncateTablesCur

 WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL

      SET @SQL=@TempTruncateTablesCur

      EXEC (@SQL)

      PRINT ' Query ::' + @TempTruncateTablesCur
            + 'Completed'
      FETCH Next FROM TempTruncateTablesCur INTO @TempTruncateTablesCur
  END
CLOSE TempTruncateTablesCur

DEALLOCATE TempTruncateTablesCur
GO

-- Create Constraint After Truncate
DECLARE @CreateConstraintQuery AS VARCHAR(4000)

DECLARE CreateConstraintQueryCur CURSOR FOR
  SELECT CreateConstraintQuery
  FROM   #CreateConstraint

OPEN CreateConstraintQueryCur
FETCH Next FROM CreateConstraintQueryCur
INTO @CreateConstraintQuery

WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL
      SET @SQL=@CreateConstraintQuery
      EXEC (@SQL)
      PRINT ' Query ::' + @CreateConstraintQuery
            + 'Completed'
      FETCH Next FROM CreateConstraintQueryCur INTO  @CreateConstraintQuery
  END
CLOSE CreateConstraintQueryCur

 DEALLOCATE CreateConstraintQueryCur

GO

Things we covered in this Post

How to drop temp table if exists in SQL Server
How to use system tables to get Primary key and foreign key Constraint
How to use Cursors in SQL Server
How to Drop Foreign Key Constraints dynamically and Recreate them
How to Truncate all tables in SQL Server Database
How to use Dynamic SQL in TSQL
How to use Variables in TSQL