Kan geen verschil genereren met de liquibase gradle-plug-in

De oplossing is om een ​​geleidelijke taak te schrijven die liquibase diffChangeLog aanroept

Maak een liquibase.gradle bestand in de hoofdmap van het project, voeg de liquibase-hibernate-extensie toe en schrijf een geleidelijke taak die de liquibase diffChangeLog aanroept commando.

configurations {
  liquibase
}

dependencies {
  liquibase group: 'org.liquibase.ext', name: 'liquibase-hibernate4', version: 3.5
}

//loading properties file.
Properties liquibaseProps = new Properties()
liquibaseProps.load(new FileInputStream("src/main/resources/liquibase-task.properties"))

Properties applicationProps = new Properties()
applicationProps.load(new FileInputStream("src/main/resources/application.properties"))

task liquibaseDiffChangelog(type: JavaExec) {
  group = "liquibase"


  classpath sourceSets.main.runtimeClasspath
  classpath configurations.liquibase
  main = "liquibase.integration.commandline.Main"

  args "--changeLogFile=" + liquibaseProps.getProperty('liquibase.changelog.path')+ buildTimestamp() +"_changelog.xml"
  args "--referenceUrl=hibernate:spring:" + liquibaseProps.getProperty('liquibase.domain.package') + "?dialect=" + applicationProps.getProperty('spring.jpa.properties.hibernate.dialect')
  args "--username=" + applicationProps.getProperty('spring.datasource.username')
  args "--password=" + applicationProps.getProperty('spring.datasource.password')
  args "--url=" + applicationProps.getProperty('spring.datasource.url')
  args "--driver=com.mysql.jdbc.Driver"
  args "diffChangeLog"
}

def buildTimestamp() {
  def date = new Date()
  def formattedDate = date.format('yyyyMMddHHmmss')
  return formattedDate
}

OPMERKING:ik heb eigenschappenbestanden gebruikt om argumenten door te geven aan het liquibase-commando, je zou de waarden rechtstreeks kunnen toevoegen, maar dat zou geen goede gewoonte zijn.

Vervolgens moet u de liquibase.gradle . toepassen bestand vanuit de build.gradle . van het project het dossier. en voeg de liquibase-afhankelijkheid toe

apply from: 'liquibase.gradle'
//code omitted
dependencies {
    compile (group: 'org.liquibase', name: 'liquibase-core', version: "3.4.2")
}

Na deze stap zou liquibase volledig zijn ingesteld.