Gescheiden waarden in een SQL-kolom splitsen in meerdere rijen

Als u SQL Server 2016+ gebruikt

U kunt de nieuwe STRING_SPLIT . gebruiken functie, waarover ik hier heb geblogd, en Brent Ozar heeft hier over geblogd.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Als u nog een versie gebruikt vóór SQL Server 2016

Maak een splitfunctie. Dit is slechts een van de vele voorbeelden die er zijn:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Ik heb hier en hier een paar andere besproken, en een betere benadering dan hier in de eerste plaats te splitsen.

U kunt nu eenvoudig extrapoleren door:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Ik raad ook aan om geen streepjes in kolomnamen te plaatsen. Het betekent dat je ze altijd tussen [square brackets] . moet zetten .