Vergelijking van SQL Server 2008 en Unicode-tekens

Oké, dus een beetje meer graven laat zien dat dit vrijwel zeker te wijten is aan een nieuwer karakter, aangezien dit ook werkt met de sql server 2008-equivalenten van latin collation, maar niet de oudere versies, d.w.z. werkt met Latin1_General_100_CI_AS , maar niet met Latin1_General_CI_AS . Om een ​​volledige lijst te krijgen van de sorteringen die deze strings correct vergelijken, heb ik gebruikt:

IF OBJECT_ID('Tempdb..#T') IS NOT NULL
    DROP TABLE #T;
IF OBJECT_ID('Tempdb..#V') IS NOT NULL
    DROP TABLE #V;

CREATE TABLE #V (A NVARCHAR(50), B NVARCHAR(50));
INSERT #V (A, B) VALUES (N'it᧠', N'it');

CREATE TABLE #T (Collation VARCHAR(500), Match BIT);

DECLARE @SQL NVARCHAR(MAX) = (SELECT N'INSERT #T (Collation, Match) 
                                        SELECT ''' + Name + ''', CASE WHEN A = B COLLATE ' + name + ' THEN 1 ELSE 0 END
                                        FROM    #V;'
                                FROM sys.fn_helpcollations()
                                FOR XML PATH(''), TYPE
                            ).value('.', 'NVARCHAR(MAX)');

EXECUTE sp_executesql @SQL;

SELECT  *
FROM    #T
WHERE   Match = 0;