SQL-transactiefout:de huidige transactie kan niet worden vastgelegd en ondersteunt geen bewerkingen die naar het logbestand schrijven

U moet altijd controleren op XACT_STATE() , niet relevant voor de XACT_ABORT instelling. Ik heb een voorbeeld van een sjabloon voor opgeslagen procedures die transacties in de TRY/CATCH-context moeten afhandelen op Afhandeling van uitzonderingen en geneste transacties :

create procedure [usp_my_procedure_name]
as
begin
    set nocount on;
    declare @trancount int;
    set @trancount = @@trancount;
    begin try
        if @trancount = 0
            begin transaction
        else
            save transaction usp_my_procedure_name;

        -- Do the actual work here

lbexit:
        if @trancount = 0   
            commit;
    end try
    begin catch
        declare @error int, @message varchar(4000), @xstate int;
        select @error = ERROR_NUMBER(),
               @message = ERROR_MESSAGE(), 
               @xstate = XACT_STATE();
        if @xstate = -1
            rollback;
        if @xstate = 1 and @trancount = 0
            rollback
        if @xstate = 1 and @trancount > 0
            rollback transaction usp_my_procedure_name;

        raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
    end catch   
end